VBS 如何发送文件上传请求， multipart/form-data

VBS 如何发送文件上传请求， multipart/form-data学习随笔images/icons/3.gif

Function GetFileData(path)
    With CreateObject("ADODB.Stream")
        .Type = 1
        .Mode = 3
        .Open
        .LoadFromFile path
        .Position = 0
        GetFileData = .Read(-1)
        .Close
    End With
End Function
 
Function GetBytes(str, cSet, bomLength)
    With CreateObject("ADODB.Stream")
        .Type = 2
        .Mode = 3
        .Charset = cSet
        .Open
        .Position = 0
        .WriteText str
        .Position = 0
        .Type = 1
        .Position = bomLength
        GetBytes = .Read(-1)
        .Close
    End With
End Function
 
Class Multipart
    Dim charset, bomLength, stream, boundary
 
    Private Sub Class_Initialize()
        Me.charset = "UTF-8"
        Me.bomLength = 3
        Set Me.stream = CreateObject("ADODB.Stream")
        Me.stream.Mode = 3
        Me.stream.Type = 1
        Me.stream.Open
        Me.boundary = "----WebKitFormBoundaryomATwYZzgiwmJSgy" ' 随便写一个,够复杂就行
    End Sub
    
    Sub WriteText(value)
        Me.stream.Write GetBytes(value, Me.charset, Me.bomLength)
    End Sub
    
    Public Function Size()
        Size = Me.stream.Size + Len(Me.boundary) + 4
    End Function
    
    Public Function GetData()
        Me.stream.Position = 0
        With CreateObject("ADODB.Stream")
            .Type = 1
            .Mode = 3
            .Open
            .Position = 0
            .Write Me.stream.Read(-1)
            .Write GetBytes("--" & Me.boundary & "--", Me.charset, Me.bomLength)
            .Position = 0
            GetData = .Read(-1)
            .Close
        End With
        Me.stream.Position = Me.stream.Size
    End Function
    
    Public Sub AddTextEntity(name, value)
        Me.WriteText "--" & Me.boundary & vbCrLf & "Content-Disposition: form-data; name=""" & name & """" & vbCrLf & vbCrLf & value & vbCrLf        
    End Sub
    
    Public Sub AddFileEntity(name, filePath, mime)
        Me.WriteText "--" & Me.boundary & vbCrLf
        Me.WriteText "Content-Disposition: form-data; name=""" & name & """; filename=""" & filePath & """" & vbCrLf
        Me.WriteText "Content-Type: " & mime & vbCrLf & vbCrLf
        Me.stream.Write GetFileData(filePath)
        Me.WriteText vbCrLf        
    End Sub
    
    Private Sub Class_Terminate()
        Me.stream.Close
        Set Me.Stream = Nothing
    End Sub
End Class
 
 
 
 
 
Dim filePath, POST_URL, multidata, xhr
 
POST_URL ="http://127.0.0.1:8080/kdxf"
 
 
Set multidata = New Multipart
multidata.AddFileEntity "picFile", "E:\40x40.jpg", "image/jpeg"
multidata.AddTextEntity "ksp_name", "1"
multidata.AddTextEntity "ksp_courtName", "1"
multidata.AddTextEntity "ksp_courtCode", "1"
multidata.AddTextEntity "ksp_serviceid", "63"
 
 
Set xhr = CreateObject("WinHttp.WinHttpRequest.5.1")
xhr.Open "POST", POST_URL, False
xhr.SetRequestHeader "X-KSP-Token", "123456"
xhr.SetRequestHeader "Content-Length", multidata.Size()
xhr.SetRequestHeader "Content-Type", "multipart/form-data; boundary=" & multidata.boundary
xhr.Send multidata.GetData()
 
WScript.Echo xhr.ResponseText

csdn 链接：https://bbs.csdn.net/topics/392385254]]>2022-09-06 22:25:282022-09-06 22:29:480684